Welcome to the Rutgers Maple Help Pages!

Plotting Options

Maple gives you many choices to modify your graphs such as axes, orientation (for 3D graphs), scaling, style, and title. These options can be included in the plot command. For example:
> plot(x^2-sin(x),x=-2..2,axes=frame, scaling=constrained);
Here is a brief overview of the choices for each plot option:
Axes can be FRAME, BOXED, NORMAL, or NONE. Notice the difference in each of the 4 graphs below:

> plot(x^2-sin(x),x=-2..2,axes=frame);

> plot(x^2-sin(x),x=-2..2,axes=boxed);

> plot(x^2-sin(x),x=-2..2,axes=normal);

> plot(x^2-sin(x),x=-2..2,axes=none);

Orientation can be included in 3d graphs. Orientation consists of two angles of the form [theta, phi]. You will learn about these angles when you study spherical coordinates. Orientation is a useful option if you want to look at a graph from a specific angle. Try:
> with(plots);
> plot3d(x^5-y^3,x=-2..2,y=-2..2,orientation=[-91,81]);
versus
> plot3d(x^5-y^3,x=-2..2,y=-2..2);
Notice that in a 3d plot, if you left-click on the graph and hold the mouse button, you can rotate the graph however you like. The angles theta and phi appear in the upper left hand corner of the maple window as you toggle the picture.

The scaling option is unconstrained by default. You can specify scaling=constrained or scaling=unconstrained. Constrained scaling guarantees the same scale will be used on each axis.

The style option changes how Maple draws your graph (with lines or dots, etc.) Style options include style=line, style=point, style=patch, or style=patchnogrid.

You may give your graph a title by adding title="my title" to a plot command.

Graphing Spacecurves
You will learn about space curves in chapter 13. Maple can graph these easily as follows:
> with(plots):
> spacecurve([cos(t),sin(t),t],t=0..4*Pi,axes=boxed);

Plotting parametric equations
Maple can also plot parametric equations in a similar way. Try:
> astr:=[(cos(t))^3,(sin(t))^3,t=0..2*Pi]:
> A:=plot(astr,color=green):
> A;

Implicit plotting in 3D and displaying multiple plots on the same axes
We saw in the beginning Maple section how to implicitly plot in 2D. When you open the plots package, you can implicitly plot in 3D as well.
To plot more than one 3D graph on the same axes, use the display command. See below:
> with(plots):
> A:=implicitplot3d(x^3+y^3=z^3,x=-5..5,y=-5..5,z=-5..5,color=green,style=patchnogrid):
> B:=plot3d(x^3+y^2,x=-5..5,y=-5..5,color=blue,axes=boxed):
> display({A,B});

Experiment with the commands above. What happens when you change the colon at the end of each of the first 3 lines to a semicolon? Do you see how each part of the A and B commands changes the final graph?

Plotting Vector Fields
Maple also makes it simple to visualize vector fields using the fieldplot command. To visualize 3D vector field, use the fieldplot3d command.
> with(plots):
fieldplot([x/(x^2+y^2+4)^(1/2),-y/(x^2+y^2+4)^(1/2)],x=-2..2,y=-2..2);

> with(plots):
> fieldplot3d([x/(x^2+y^2+4)^(1/2),-y/(x^2+y^2+4)^(1/2),z],x=-2..2,y=-2..2,z=-2..2,axes=boxed);

[back to the top | advanced plotting commands | fun with vectors | advanced tools for solving equations |integral/derivative tutor | more calculus 3 tools]

## Fun with Vectors

The VectorCalculus package contains many useful tools. When you learn to compute these quantities by hand throughout the semester, you may appreciate how "quickly" Maple can compute.

When you open the VectorCalculus package, you can write vectors as follows:
> with(VectorCalculus):
> W:=<2,3,5>;
Your vector need not be numeric though! Try, for example:
> V:=<t^2,t^3,t^4+1>;

Cross product
You can compute the cross product of vectors V and W in two ways:
> with(VectorCalculus):
> CrossProduct(V,W);

> V &x W;

Dot product
You can also compute the dot product of V and W in two ways:
> with(VectorCalculus):
> DotProduct(V,W);

> V.W;

ArcLength
> with(VectorCalculus):
> ArcLength(<cos(t),sin(t),t>, 0..6*Pi );

Directional Derivative
> with(VectorCalculus):
> DirectionalDiff( x^2+y^2, <1,1>, [x,y] );

> with(VectorCalculus):

Tangent, Normal, and Binormal Vectors
> with(VectorCalculus):
> TNBFrame(<cos(t),sin(t),t>, t );

Note that this returns a list of 3 vectors: T, then N, then B.

Curl and Div
> with(VectorCalculus):
> v:=VectorField(<x,y,z>,'cartesian'[x,y,z]);

> Curl(v);

> Divergence(v);

[back to the top | advanced plotting commands | fun with vectors | advanced tools for solving equations |integral/derivative tutor | more calculus 3 tools]

## Advanced tools for solving equations

We already saw how to use solve systems of equations. You can also use Maple to solve a system of equations with more than one variable. Try:
> solve({x+y=2,x-y=3},{x,y});

It may happen that you want to solve a more complicated set of equations. For example, try:
> solve({x^2+y^3=2,x-y=3},{x,y});

The result is true, but not numeric. (If you get a solution that includes RootOf, it is a hint that your answer involves complex numbers!) If you would like to see numeric answers, you should try the allvalues command. For example,
> A:= solve({x^2+y^3=2,x-y=3},{x,y}):
> allvalues(A);

Notice that, if possible, allvalues returns all exact (both real and complex!) solutions to the system of equations.
Small catch: If you ask Maple to solve a random quintic (degree 5 polynomial), it cannot perform miracles, and allvalues will return another RootOf statement.
[back to the top | advanced plotting commands | fun with vectors | advanced tools for solving equations |integral/derivative tutor | more calculus 3 tools]

## Integral/Derivative Tutor

Maple can help you solve complicated integrals and derivatives step by step. To see this in action try the following:
> with(Student[Calculus1]):
> IntTutor();
A pop-up window should appear. Enter the function you want to integrate in the box at the top of the page. Try different integration rules by pressing the buttons on the right side of the box. If you get stuck, you can ask Maple for a hint.

For practice with derivatives, try
> DiffTutor();

[back to the top | advanced plotting commands | fun with vectors | advanced tools for solving equations |integral/derivative tutor | more calculus 3 tools]

## More Calculus 3 tools

Maple is equipped with many other tools that are useful for Calculus 3. To see what it can do with Taylor Approximations, Cross-Sections, Directional Derivatives and the Gradient, The Hessian and the Second Derivative Test, Integrals in Multivariate Calculus, Integral Approximations, The Jacobian, Change of Variables, Lagrange Multipliers, Function Average, Surface Area, and Center of Mass, enter:
> ?examples/MultivariateCalculus;
A new Maple worksheet will open with many interesting examples.

[back to the top | advanced plotting commands | fun with vectors | advanced tools for solving equations |integral/derivative tutor | more calculus 3 tools]