--Worksheet 1, Mathematics 535, Fall 2002
--
--Parametric varieties: Computation of the ideal vanishing on a parametric set
--If f_i/g_i are rational functions of x_j, make a ring homomorphism from
---the ring of polynomials in z_i to the quotient of the ring generated by
--x_j, y_j modulo the ideal generated by g_i*y_i-1, by sending z_i to f_i*y_i
--The kernel is the set of polynomials vanishing on the expressions f_i/g_i 

--Goals: compute equations for some parametric varieties, such as singular plane
---------cubics, affine toric varieties, and some surfaces in 3-space

-- The cubic examples from Harris page 15
R=QQ[x,y,z]
S=QQ[s,t]
map(S,R,{s^3,s*t^2,t^3})   --note the target ring S comes first !

ker oo  	       	   --recall oo means the preceding result,ooo two back       	     	   
                           --the ideal of polynomials vanishing on (s^3,st^2,t^3)


degree oo     	   	   --the degree of  the generator of the ideal


map(S,R,{s^3,s*t^2-s^3,t^3-s^2*t})
ker oo






---------------	    	---- Equations for affine toric varieties


T=QQ[s,t]/ideal(s*t-1)    -- the ring QQ[t,t^{-1}]
map(T,R,{t,t^2,t^3})      -- the affine toric variety {(t,t^2,t^3)}
ker oo	   	     	  -- ideal of polynomials vanishing on affine twisted cubic

T2=QQ[s,t,u,v]/ideal(s*t-1,u*v-1)

map(T2,R,{s*v^2,s^2*u^2,t*u})

ker oo	   	     	  -- ideal vanishing on points (s/u^2,s^2u^2,u/s)

--Fact :affine toric varieties have ideals generated by differences of monomials



--Macaulay has a builtin function to make the ideal of the affine toric
--variety given by s^e_i * t ^ a_i where a_i are positive integers, e_i+a_i=d
--the ideal is homogeneous, defining a projective variety
--Here is the Macaulay documentation of this function
help monomialCurveIdeal 


--Some examples of our own
B=QQ[a_0..a_12]
monomialCurveIdeal(B,{1,2,3})  --ideal of twisted cubic in P^3

--making a list
1..5
---ideal of the rational normal curve in projective 5 space

monomialCurveIdeal(B,1 .. 5)


---Examples of some surface parameterizations

clearAll       	    	 --clear all previously defined objects
R=QQ[x,y,z]

S=QQ[u,v]
T=QQ[r,s,t]

--A parameterization of a projective surface by polynomials in r,s,t


par={-(s+r)*t^2 + (s^2+2*r^2)*t - s^3 + r*s^2 - 2*r^2*s - r^3, 
      t^3 - (s+r)*t^2 + (s^2+2*r^2)*t + r*s^2 - 2*r^2*s + r^3, 
      -t^3 + (s+r)*t^2 - (s^2+2*r^2)*t + 2*r*s^2 - r^2*s + 2*r^3, 
      (s-2*r)*t^2 + (r^2-s^2)*t + s^3 - r*s^2 + 2*r^2*s - 2*r^3} 

R4=QQ[x,y,z,w]

g=map(T,R4,par)

ker g   	---Note the equation of Zariski closure



---The parameterization of the variety above was given by N. Elkies 
---see http://www.math.harvard.edu/~elkies/4cubes.html

---Let's find how many places the parameterization is undefined
degree radical ideal par

-- A parameterization for use in Problem 1 below


par1={-r^4 + 2*s*r^3 - 3*s^2*r^2 + (2*s^3 + t^3)*r + (-s^4 - 2*t^3*s),
 r^4 - 2*s*r^3 + 3*s^2*r^2 + (-2*s^3 - t^3)*r + (s^4 - t^3*s), 
-t*r^3 + 3*t*s*r^2 - 3*t*s^2*r + (2*t*s^3 + t^4),
 t*r^3 + (t*s^3 - t^4)}

--- Another surface parameterization in P^3





par2={-2*s*t^8 - 4*s*r*t^7 - 2*s*r^2*t^6 + 3*s^4*t^5 - 3*s^4*r^2*t^3 - s^7*t^2 + s^7*r*t - s^7*r^2, -t^9 - 2*r*t^8 - r^2*t^7 + 3*s^3*t^6 + 3*s^3*r*t^5 - 2*s^6*t^3 + 2*s^6*r*t^2 + s^6*r^2*t, t^9 + 2*r*t^8 + r^2*t^7 + 3*s^3*r*t^5 + 3*s^3*r^2*t^4 - s^6*t^3 - 2*s^6*r*t^2 + 2*s^6*r^2*t, -s*t^8 - 2*s*r*t^7 - s*r^2*t^6 + s^7*t^2 - s^7*r*t + s^7*r^2}


gh=map(T,R4,par2) 	--the map to take the kernel of to find equations of Zariski closure



--PROBLEMS
--1. Find the equations of the varieties parameterized by par1 and par2 above 
---- Show that par1 is undefined at 5 points in the projective plane, so that
---- it is not projectively equivalent to Elkies parameterization      
--2. Find the equations of the affine toric variety parameterized by
prob2={u,u*v,u*v^2}

--3. Find the equations of the affine toric variety parameterized by
prob3={u*v,u, v^2}